TILEMASTER2004 DATA V1
SCRIPT: 75
0 CheckFlag 6 2 50
0 CCheckFlag 4 >= 2 30
0 Look
0 AddKeyWords bye 2 look 3 name 4 job 5 now 6 simple 6 fisherman 6 fishing 6 fortress 7 bandits 7 leader 8 noble 8 hero 8 overran 9 killed 9 attack 9 takroth 10 proud 11 serve 11 raldban 11 friends 12 few 14 lucky 15 away 15 villains 16 war 17
0 Message "Yes?"
1 DoConvInput "Sorry?"
2 Message "Goodbye"
0 BREAK
3 Look
0 GOTO 1
4 Message "Verg"
0 GOTO 1
5 Message "Just a simple fisherman ... now."
0 GOTO 1
6 Message "While I enjoy fishing, I once served in a great fortress.  Then bandits came and overran us ... killed almost everyone, including many of my friends.  A few of us were lucky enough to get away."
0 GOTO 1
7 Message "The bandit Takroth now rules there.  They use it as a base of operations for their raids.  What was once a bastion of heroism is now nothing more than a den of thieves.  Our leader was a great hero who helped defend the countryside, a noble as one should be.  I was very proud to serve him."
0 GOTO 1
8 Message "Lord Raldban.  I did not see him fall, but I fear the worst."
0 GOTO 1
9 Message "Suddenly, without warning.  We had waged war against the villains of the land and they struck back.  Our warriors fought bravely and lost.  The tales of the bards may say otherwise, but good does not always win.  It is as simple and horrible as that."
0 GOTO 1
10 Message "I know little of him, only what I have heard afterwards.  I did not know who he was during the attack."
0 GOTO 1
11 Message "So very few nobles are worthy of servitude.  The rest are nothing more than thieves and slavelords.  I no longer serve anyone."
0 GOTO 1
12 Message "Most are now with the gods."
0 GOTO 1
14 Message "We are scattered, and I do not know where they are."
0 GOTO 1
15 Message "We live only because we servants were not seen as a threat."
0 GOTO 1
16 Message "I wonder if there is anyone left to defend against villains like Takroth."
0 GOTO 1
17 Message "Bandits, monsters, corrupt leaders, and worse; anyone or anything who would threaten the common good.  Lord Raldban knew this was the responsibility of a noble."
0 GOTO 1
30 Look
0 AddKeyWords bye 32 look 3 name 4 job 5 now 6 fisherman 6 fortress 33 keep 33 bandits 34 takroth 34 overran 35 killed 35 raldban 38 friends 36 few 36 lucky 15 villains 37 war 17
0 Message "Have you heard?!  I can't believe it!  The keep was retaken and Lord Raldban is alive!  I'm just getting ready to leave."
0 SetFlag 4 3
31 DoConvInput "Sorry?"
32 Message "Yes, I should go, too."
0 RemoveMapObj Creature 0 -DELETE
0 SetFlag 6 1
0 BREAK
33 Message "The bandit Takroth was ruling there, but no more!"
0 GOTO 31
34 Message "The bandits are gone!"
0 GOTO 31
35 Message "Suddenly, without warning.  We had waged war against the villains of the land and they struck back.  Our warriors fought bravely and lost.  But it seems that good has won in the end, after all!"
0 GOTO 31
36 Message "Some may yet live!"
0 GOTO 31
37 Message "With Takroth dead and Lord Raldban back, we'll see how they fare now!"
0 GOTO 31
38 Message "I cannot believe he's alive!  Now, there is hope!"
0 GOTO 31
50 Look
0 AddKeyWords bye 2 look 3 name 4 job 52 dinner 53 fish 53 steward 53 raldban 54 estate 55 place 55 warrior 56 heroes 56 bandits 56 takroth 56
0 CMessage -PCNAME "!  I hope you are well!" -NL
0 GOTO 1
52 Message "[He grins]  Thanks to you, I am once again the royal head steward.  You should join us for dinner, we're serving fish!"
0 GOTO 1
53 Message "I love fishing, but there's nothing like being a part of this noble estate.  This place is my home, the people here are my family, and the warriors are true heroes under the guidance of Lord Raldban.  I may not be a warrior, but I am helping in my own small way."
0 GOTO 1
54 Message "I think he's upstairs right now.  So very few nobles are worthy of servitude.  The rest are nothing more than thieves and slavelords."
0 GOTO 1
55 CMessage "Thanks to you, " -PCNAME ", once again a bastion of heroism!" -NL
0 GOTO 1
56 Message "Our warriors are few, but seem to be managing.  Certainly, it helps that Takroth's huge group of bandits is no more."
0 GOTO 1
