TILEMASTER2004 DATA V1
SCRIPT: 75
0 Party -CHECKSAVESPC 0 200
0 AddKeyWords bye 2  look 3  name 4  job 5  mariah 20  story 21  father 22  wizard 23  apprentice 23  powerful 24  travel 25  stories 26  heroes 26  quest 26  mage 27  brother 28  king 29  join 100
0 Look
0 M "Hello.  What do you need?"
1 DoConvInput "Sorry, I cannot help with that."
2 M "Farewell."
0 BREAK
3 Look
0 GOTO 1
4 M "My name is Riahma, a rearrangement of the name of a famous mage from a famous story that my father dearly loves, as do I.  Maybe by irony or maybe by the fate of the gods, I followed in her footsteps and am now a wizard myself.  Well, an apprentice.  I have a long way to go before I am as powerful as Mariah!"
0 GOTO 1
5 M "I am a wizard.  Well, an apprentice wizard, anyway."
0 GOTO 1
20 M "Yes, the story says she eventually became very powerful."
0 GOTO 1
21 M "The best story ever written.  But it would take a very long time to tell you about it so please don't get me started or I'll never stop."
0 GOTO 1
22 M "The king.  That makes me a princess, but I prefer to think of myself as less tied to nobility and more to my profession as a wizard.  My elder brother is the one who will eventually take the throne, so I am far more free to pursue other matters."
0 GOTO 1
23 M "I think I need to travel to improve my skills further."
0 GOTO 1
24 M "Her skills eventually increased dramatically after she was asked to join a group of heroes on an epic quest."
0 GOTO 1
25 M "I couldn't go alone.  But I couldn't go with anyone here, either; they're too few and need to focus on other urgent matters, those that would go with me would just protect me to the point where they'd get in the way, and frankly, they're not very skilled and would probably get themselves killed trying to protect me.  What I really need is to join with a group of heroes on a quest.  Alas, I have yet to meet anyone like in the stories."
0 GOTO 1
26 M "My favorite story is one with a wizard named Mariah who is asked to join a group of heroes in an epic quest.  By the end of the quest she became very powerful."
0 GOTO 1
27 M "Simply a foreign name for a wizard."
0 GOTO 1
28 M "He is currently away on business in a distant land."
0 GOTO 1
29 M "My father is a wonderful man and a wonderful ruler.  I love him dearly.  And I get the impression that his subjects do appreciate his wise and benevolent rulership, though I have not spent much time amoungst them.  While I love the comforts of the castle, I really need to travel more."
0 GOTO 1
100 Check FEATURE-PARTY == 1 101
0 M "Sorry, I really wish I could, but something tells me the gods aren't ready for me to do so just yet.  Maybe someday.  I'm just going to keep studying here for now."
0 GOTO 1
101 Check CLASS == 4 102
0 Party -GETCLASSPC 4 -CHECKPC 102
0 GOTO 103
102 M "Actually, I'd better not.  But thank you for asking."
0 M "[This NPC is designed not to join if you are the same class but there are other NPC's that will join.]"
0 GOTO 1
103 CM "[She smiles and sizes you up carefully.]  This is exactly the opportunity I've been waiting for!  But first can you tell me a little bit about yourself? "
0 Verify 105
0 M "Alright then, maybe later.  What else can I do for you?"
0 GOTO 1
105 M "[You tell her about your experiences.]"
0 Pause
0 Check LEVEL >= 12 106
0 M "That is facinating.  I'd go immediately, but I have some issues of royalty to which I must first attend.  You should return every so often and tell me about your new experiences.  At some point I'm quite sure that I will be ready to travel with you if you are still willing.  So just ask me again later if you would like for me to join in your quest."
0 GOTO 1
106 CM "The time is right for me to travel with you.  Do you want for me to join your party? "
0 Verify 110
0 M "Alright.  Well, if you change your mind later please let me know."
0 GOTO 1
110 M "Please give me a few moments to get ready.  [She disappears for a little while then comes back with her gear.]  I am ready.  Let us journey onward!  Uh, sorry, a reference to my favorite story ... got a little excited there ... *ahem!* ... anyway ... let's go!"
0 Pause
0 Party -ADDPC "PCJ2.dat" 101 -CTOPC 0 0
0 CheckState INC 115
0 RemoveMapObj Creature 0 -DELETE
0 BREAK
115 M "That's alright.  Just come back when you are ready."
0 GOTO 1
200 CM "Are you ready for me to rejoin? "
0 Verify 210
0 M "Alright.  Please let me know when you are ready."
0 BREAK
210 Party -ADDPC SAVED 101
0 CheckState INC 215
0 RemoveMapObj Creature 0 -DELETE
0 BREAK
215 M "That's alright.  Just come back when you are ready."
0 BREAK
