TILEMASTER2004 DATA V1
SCRIPT: 75
0 Look
0 AddKeyWords bye 2  look 3  name 4  job 5  no 6  only 10  remaining 10  old 10  destroyed 10  inn* 11  family 11  smaller 12  new 12  nice 12  outpost 14  thing 14  strange 14  wall 14  guard* 15  moat 16  fishermen 17  river 17  help 18  Friel 19  town 19  joreth 20  council* 21  yes 100  y 100  room 100
0 M "Welcome!  I am the innkeeper.  Would you like a room?"
1 DoConvInput "I'm sorry, I'm not really sure."
2 M "Good day"
0 BREAK
3 Look
0 GOTO 1
4 M "Thank you for asking!  I am known as Emitsyal.  Well met!"
0 GOTO 1
5 M "I am the innkeeper of the only inn remaining in Friel."
0 GOTO 1
6 M "Sure, no problem.  So what do you need?"
0 GOTO 1
10 M "Sadly, my old inn outside of town was destroyed by monsters not long ago.  It was really a nice one, very old ... been in my family for many years.  This new one is much smaller, but I've tried to make it nice.  The little farms and shops outside of the main part of town have always been in some danger without the protection of the guards and moat, but that inn stood for countless years.  Monsters and bandits have always been a problem, but it was the increase in them over recent years that lead to the destruction of my old inn.  I wish someone would find out why!"
0 GOTO 1
11 M "My father was also an innkeeper, as was my grandfather and great-grandfather, who built my old inn."
0 GOTO 1
12 M "This new inn replaced the old guard outpost ... thing ... that was here previously.  The guard say they didn't mind since it was kind of strange ... sort of part of a wall that was built many years ago as part of one that was going to completely surround the town but never completed after they decided to use just the moat instead.  They built a guard tower just to the south of here using many of the same stones.  Since they didn't need them all, they let me use many of the others for this very building. [He points around at the walls]"
0 GOTO 1
14 M "Well, it served as kind of a lookout post, but the shape and position really didn't make much sense."
0 GOTO 1
15 M "They are very dedicated and do a great job.  Joreth is their leader and the lead councilman.  And he's the only one I know who is truly trying hard to find out why the monsters and bandits have become so numerous, but he needs help because his hands are already so full just trying to protect Friel."
0 GOTO 1
16 M "Well, it isn't quite like a moat arond a castle, all stagnant and such.  I'm not sure what to call it.  It is really more a diversion of the river.  The local fishermen even say that the fishing is sometimes better than in the main river.  Even so, everyone still drinks from the well since it is more clean."
0 GOTO 1
17 M "A lot of the people both inside town and living outside the main city are fishermen.  We may not live right on the coast, but the river is a great source of fish.  I'm glad we don't live on the coast, too many dangers at sea these days."
0 GOTO 1
18 M "If you want to help him, he's nearly always in town.  He doesn't stay in one place, though, so you may have to look around for him.  And by the way, if you help him, you help all of us, so on behalf of all of the citizens of Friel we would thank you!"
0 GOTO 1
19 M "I love this town.  May it stand forever!  I desperately hope that we are not overrun by all the monsters and bandits that have been steadily increasing over the last few years.  The guards are all too few and many of the smaller settlements have already been overrun, not to mention the places outside of the protection of the main town like many farms and such places ... my old inn was one of those before it was destroyed not long ago.  Joreth, our lead councilman, was kind enough to help me rebuild inside the main part of the city. [He pauses and shakes his head]"
0 Pause
0 M "Anyway, I'm sorry, you asked about Friel.  Well, it is the largest settlement on the west coast.  The large river to the east runs through the lands until it hits the coast to the north.  Sadly, the small village there was totally wiped out many years ago by horrible sea monsters that came out of the waters in the middle of the night.  Sad, that.  No one wants to rebuild after that.  Anyway, the citizens here are a mix of fishermen, farmers, craftsmen, and other merchants such as myself.  The gods of light have blessed us with a river full of fish and fertile soil.  You should ask Joreth if you want to know more; he's the only one I know who loves Friel even more than I.  And he can probably explain things about the council better than I can."
0 GOTO 1
20 M "Joreth is the lead councilman and a guardsman.  He's known throughout Friel as one of the most kind and heroic people that you'll ever meet.  He leads us by service, wisdom, and humility, not brutality, wealth, and deception like so many rulers.  Anyway, he's got his hands really full trying to defend Friel.  He'll be somewhere in town, but is always very, very busy so you may have to look around.  Oh, and he's looking for help if you are willing."
0 GOTO 1
21 M "Well, Joreth is really the expert on that, but what I can tell you is that Friel is ruled by a council of us normal people rather than by corrupt, greedy nobles.  Due to his worthiness as a leader, Joreth was selected as the lead councilman."
0 GOTO 1
100 CM "They are 3 gold, which I hope you to find to be a fair price.  Do you want it? "
0 Verify 110
0 CM "No problem.  Is there anything else? "
0 Verify 101
0 GOTO 103
0 M "Sure, just let me know if you change your mind about the room."
0 GOTO 2
101 M "Sure, how can I help you?"
0 GOTO 1
110 Pay 3 1
0 M "The room is small, but I hope you find it to be comfortable."
0 Pause
0 SetMapCreatures RESETPOS 7 15 9 17
0 SetMapCreatures SHIFTPOS 0 4 7 15 9 17
0 Teleport 0 8 15
0 CM -PARTYONLY "Your party finds various places to sleep." -NL
0 Pause
0 M "Although it is a bit cold, the room is clean and otherwise reasonably comfortable, and it is nice to sleep on a bed."
0 Pause
0 CM "You drift off"
0 Script 501
0 AlterPCTile 1004
0 Script 500
111 CM -NL
0 AlterPCTile BASE
0 DeleteTile 1004
0 DeleteFrame 1004
0 M "You wake up well-rested."
0 PartyIterator -INIT
1 PartyIterator -ETAG N2 -PNAME
0 GivePCMB 2 10 20
0 Heal 8% SKIPNE
0 GiveSP 80%
0 GOTO P1
2 BREAK
