TILEMASTER2004 DATA V1
SCRIPT: 200
0 AddKeyWords bye 3  no 3  name 5  job 5  1 110  2 120  plays 10  play 10  Marpo* 200  V'Colo 200  scroll 200  Marco 250  Polo 250  Volo 250
0 M "Good day, and welcome to the theater!  Today we have a wonderful performance of an exotic instrument called an 'E flat recorder'.  We also have a harpsichorde performance of fantastic pieces by some of the greatest composers of all time.  Payment is only 4 gold for all performances.  You'll find our theater is very comfortable and has wonderful accoustics.  It is just upstairs."
0 Pause
1 M "Would you like to attend a performance?"
0 M "1: E flat recorder for 4 gp"
0 M "2: Harpsichorde for 4 gp"
0 CM -PARTYONLY "The price is per member of your party" -NL
2 DoStringInput -PROMPT -IMESSAGE "Hmm?  " -NNL -ITAG 1
3 M "Farewell, and do return soon."
0 BREAK
5 M "I'm the theater manager.  We have had a variety of shows here over the years, but recently have been focusing on music.  However, our plays are also very popular and so at some point we'll probably put on some more of them again."
0 Pause
0 GOTO 1
10 M "I'm sorry, we are not currently offering any plays."
0 Pause
0 GOTO 1
200 CheckItem 275 1 210
0 Flag 37 -BRANGE 3 5 -CHECK >= 1 -TAG 201
0 M "Yes, Marpo V'Colo.  Alas, all 7 parts of one of the greatest plays of all time, lost."
0 Pause
0 GOTO 1
201 M "Thank you again, my friend!"
0 Pause
0 GOTO 1
210 CheckBFlag 37 1 1 211
0 M "You must certainly be mistaken, but I'll take a look.  [He retrieves a small magnifying glass and carefully examines the scroll.  He pauses for a moment and looks stunned.]  Um ... [He takes another careful look then looks up.]  Uh ... [He looks at you with an astonished expression.  He has turned a little pale, begins to shake a little, and you think you might see a tear forming in one of his eyes.  You begin to worry you're going to have to call for a healer before his head explodes or something.]  Um ... ok ... uh ... yes ... this does in fact appear to be authentic, and, uh, yes ... this is good.  This is VERY, VERY good.  Um, uh ..."
0 SetBFlag 37 1 1
0 Pause
0 GOTO 215
211 Flag 37 -BRANGE 3 5 -CHECK >= 1 -TAG 212
0 GOTO 215
212 M "Another part of the story!  [He once again uses the magnifying glass to verify it.]  It is authentic!"
0 Pause
215 M "Please, would you be willing to part with this?  You would be doing a wonderful thing if you did so, as we would then be able to bring this masterpiece once again to the public for the first time in many decades!"
0 Pause
0 M "We are not wealthy, so I can only offer you a tiny reward and our heartfelt gratitude."
0 CM "What do you say? "
0 Verify 220
0 M "Well, please reconsider and let me know when you change your mind, as I'm sure you'll do the right thing and allow everyone to once again enjoy this masterpiece.  Please excuse me."
0 BREAK
220 M "On behalf of myself, the theater staff, and, most importantly, the public who will soon once again be able to delight in this masterpiece, I thank you!!! [He bows formally.]"
0 TakeItem 275
0 Give XP 100 -SHOW
0 GiveItem 1 100 -SHOW
0 Flag 37 -BRANGE 3 5 -SET +1
0 Flag 37 -BRANGE 3 5 -CHECK == 7 -TAG 225
221 Pause
0 M "Don't worry, I will be very careful with this, particularly given the age of this scroll makes it more fragile than a little egg.  We were already planning on setting up a new play for early next spring, so this one would be perfect!  Thank you again!!!  [He then excitedly turns all of his attention to the scroll.]"
0 BREAK
225 Pause
0 M "You have returned all 7 parts!  I can't believe it!  Thank you so, so much!  Here is something a little extra from my own, personal funds.  And don't say no; you deserve it, my friend!"
0 Give XP 300 -SHOW
0 GiveItem 1 300 -SHOW
0 GOTO P221
250 CM "The name you used is an ancestor of a famous explorer from long ago named Marpo V'Colo.  Are you asking about the play by that name? "
0 Verify 200
0 M "Well, I'm not sure then."
0 Pause
0 GOTO 1
110 M "You're in luck.  That performance starts in just a few minutes."
0 Pause
0 M "[You hand him the payment.]"
0 Util -SETAMOUNT 1
0 Party -SETAMOUNT
0 Pay 4 1 -QMULT
0 Pause
0 Teleport 76 5 23
0 AddKeyWords _RETURN 101
0 GOTO N500
101 NOOP
0 SetRedraw 0
0 SetView 5 17
0 AlterTiles 146 5 17
0 SetRedraw 1
0 M "[You look up at the stage.  A minstrel carrying a small recorder steps into view and bows.]"
0 Pause
0 M "Well met!  I am here to perform my E flat recorder for you.  [He holds up the instrument, a small, black wind instrument with silver keys.]  As you can see, this rare instrument is noticably smaller than the much more common B flat recorder, and is therefore higher pitch.  It is an instrument that I dearly love.  Anyway, I hope you will enjoy it.  [He places the instrument to his mouth pointing forwards and down and begins to play.  The sound is bright and cheery, and at the same time very beautiful.  While it is powerful and high, he carefully controls the pitch so that it stays in tune as the sparkling notes dance by.]"
0 Pause
0 CRandom 80 -  5 111  15 112
0 M "[He performs competently and you find the experience quite entertaining.]"
0 Pause
0 M "[The audience applauds.]"
0 PartyIterator -INIT
1 PartyIterator -ETAG N115 -PNAME
0 GivePCMB 3 10 20
0 GivePCMB 5 2 5
0 GOTO P1
111 M "[He performs competently at first, but then the instrument suddenly makes a horrible shrieking sound.  He stops, mutters something about a reed, adjusts something, and begins playing again, but you get the feeling he is struggling a bit.]"
0 Pause
0 M "[When he reaches the end, the audience responds with some light, scattered applause.  A bearded man next to you smirks and says, 'He should have played the B flat!']"
0 PartyIterator -INIT
1 PartyIterator -ETAG N115 -PNAME
0 GivePCMB 3 4 8
0 GOTO P1
112 M "[He performs quite expertly and puts a great deal of artistry into it.  You are drawn into the music, feeling very inspired by it.  After it ends, he bows, smiling widely, and you realize he has quite probably exceeded himself.]"
0 Pause
0 M "[The audience applauds enthusiastically.  All except a bearded man next to you, who scowls and mutters, 'It would have been a lot better if he'd played the B flat.']"
0 PartyIterator -INIT
1 PartyIterator -ETAG N115 -PNAME
0 GivePCMB 3 15 30
0 GivePCMB 5 5 10
0 GOTO P1
115 SetRedraw 0
0 AlterTiles 24 5 17
0 SetView PC
0 SetRedraw 1
0 Pause
0 M "[You stand up.]"
0 AlterPCTile BASE -SETDEF
0 DeleteTile 1004
0 DeleteFrame 1004
0 AutoSave
0 BREAK
120 M "You're in luck.  That performance starts in just a few minutes."
0 Pause
0 M "[You hand him the payment.]"
0 Util -SETAMOUNT 1
0 Party -SETAMOUNT
0 Pay 4 1 -QMULT
0 Pause
0 Teleport 76 3 22
0 AddKeyWords _RETURN 102
0 GOTO N500
102 NOOP
0 SetRedraw 0
0 SetView 5 17
0 CreateTile 1005 -FRAME 0 1005 -NOREV
0 CreateFrame 1005 -LOAD 1005.til -NOREV
0 AlterTiles 1005 5 17
0 AlterTiles 146 4 17
0 SetRedraw 1
0 M "[You look up at the stage.  A minstrel steps into view and bows, then sits down at a harpsichorde.]"
0 Pause
0 M "Well met!  I will perform a selection of compositions for the harpsichorde by Ormanark, Depimod, and Iniex, as well as an original composition of my own.  [He begins to play.  The harpsichorde is a lovely keyboard instrument, powerful and evocative.  The Ormanark piece is your favorite, being extremely inventive and experimental, and yet still having a wonderful melody.  That said, you also enjoy the others a great deal.  The Depimod piece is quite dark and emotional.  The Iniex piece is a slow, beautiful ballad.  His original piece is quite experimental, with a hybrid of influences from the preceding composers, and is also very enjoyable.]"
0 Pause
0 CRandom 80 -  5 121  15 122
0 M "[He performs competently and you find the experience quite entertaining.  He stands up and bows, smiling.]"
0 Pause
0 M "[The audience applauds.]"
0 PartyIterator -INIT
1 PartyIterator -ETAG N125 -PNAME
0 GivePCMB 3 10 20
0 GOTO P1
121 M "[Unfortunately, he makes quite a few mistakes that take away from your enjoyment of the pieces.  After he finishes, he stands up and bows slightly, although he looks a little upset.]"
0 Pause
0 M "[The audience responds with some light, scattered applause.]"
0 PartyIterator -INIT
1 PartyIterator -ETAG N125 -PNAME
0 GivePCMB 3 4 8
0 GOTO P1
122 M "[He performs quite expertly and really brings the full power of the pieces together.  After it ends, he bows, smiling widely, and you realize he has quite probably exceeded himself.]  Thank you, I really enjoyed performing for you."
0 Pause
0 M "[The audience applauds enthusiastically.]"
0 PartyIterator -INIT
1 PartyIterator -ETAG N125 -PNAME
0 GivePCMB 3 15 30
0 GOTO P1
125 SetRedraw 0
0 AlterTiles 24 4 17 5 17
0 SetView PC
0 SetRedraw 1
0 Pause
0 DeleteTile 1005
0 DeleteFrame 1005
0 M "[You stand up.]"
0 AlterPCTile BASE -SETDEF
0 DeleteTile 1004
0 DeleteFrame 1004
0 AutoSave
0 BREAK
500 M "[You go upstairs and find a seat.]"
0 CM -PARTYONLY "[The rest of your party also finds various places to sit or stand.]" -NL
0 Pause
0 SetMapCreatures RESETPOS 2 20 7 25
0 Script 504
0 AlterPCTile 1004
0 M "[You sit down.]"
0 Pause
0 DoKeyWord _RETURN
